|
arri
Utente Master
Regione: Lombardia
14951 Messaggi |
 Inserito il - 06 settembre 2010 : 14:55:50
|
riposto discussione persa nel server precedente
http://cadtutor.org/forum/showthread.php?12233-Change-layers-on-command-line-(writing-a-script)&s=fe1171bdb0e81d395285bbd0c6f6bfef&p=68566#post68566
(defun c:unvisible(/ objLst objLst sucCount errCount)
(vl-load-com)
(princ "\n<<< Select object to make unvisible >>> ")
(if
(setq objSet(ssget))
(progn
(setq objLst
(mapcar 'vlax-ename->vla-object
(vl-remove-if 'listp
(mapcar 'cadr(ssnamex objSet))))
sucCount 0
errCount 0); end setq
(foreach obj objLst
(if
(vl-catch-all-error-p
(vl-catch-all-apply
'vla-put-visible
(list obj :vlax-false)))
(setq errCount(1+ errCount))
(setq sucCount(1+ sucCount))
); end if
); end foreach
(princ
(strcat "\n"(itoa sucCount) " becomes unvisible "
(if(/= 0 errCount)
(strcat ", " (itoa errCount) " were on locked layer! ")
""); end if
); end strcat
); end princ
); end progn
); end if
(princ)
); end of c:unvisible
(defun c:visible(/ objLst objLst sucCount errCount)
(vl-load-com)
(setq sucCount 0
errCount 0
objSet(ssget "_X" '((60 . 1)))
); end setq
(if objSet
(progn
(setq objLst
(mapcar 'vlax-ename->vla-object
(vl-remove-if 'listp
(mapcar 'cadr(ssnamex objSet)))))
(foreach obj objLst
(if
(vl-catch-all-error-p
(vl-catch-all-apply
'vla-put-visible
(list obj :vlax-true)))
(setq errCount(1+ errCount))
(setq sucCount(1+ sucCount))
); end if
); end foreach
(princ
(strcat "\n"(itoa sucCount) " becomes visible "
(if(/= 0 errCount)
(strcat ", " (itoa errCount) " were on locked layer! ")
""); end if
); end strcat
); end princ
); end progn
(princ "\n<<< Unvisible objects not found >>> ")
); end if
(princ)
); end of c:visible
|
|
Lisp Per Rendere Invisibili Le Entità In Autocad
